"Battlemap" -> "Battle".

4 files changed, 805 insertions, 0 deletions

diff --git a/src/battle/game-logic/btl_movement.erl b/src/battle/game-logic/btl_movement.erl
new file mode 100644
index 0000000..87b1806
--- /dev/null
+++ b/src/battle/game-logic/btl_movement.erl
@@ -0,0 +1,60 @@
+-module(btl_movement).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export([cross/4]).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec cross
+   (
+      btl_battlemap:type(),
+      list(btl_location:type()),
+      list(btl_direction:enum()),
+      non_neg_integer(),
+      btl_location:type()
+   )
+   -> {btl_location:type(), non_neg_integer()}.
+cross (_Battlemap, _ForbiddenLocations, [], Cost, Location) ->
+   {Location, Cost};
+cross (Battlemap, ForbiddenLocations, [Step|NextSteps], Cost, Location) ->
+   NextLocation = btl_location:apply_direction(Step, Location),
+   NextTileClassID = btl_battlemap:get_tile_class_id(NextLocation, Battlemap),
+   NextTileID = btl_tile:class_id_to_type_id(NextTileClassID),
+   NextTile = btl_tile:from_id(NextTileID),
+   NextCost = (Cost + btl_tile:get_cost(NextTile)),
+   IsForbidden =
+      lists:foldl
+      (
+         fun (ForbiddenLocation, Prev) ->
+            (Prev or (NextLocation == ForbiddenLocation))
+         end,
+         false,
+         ForbiddenLocations
+      ),
+
+   IsForbidden = false,
+
+   cross(Battlemap, ForbiddenLocations, NextSteps, NextCost, NextLocation).
+
+-spec cross
+   (
+      btl_battlemap:type(),
+      list(btl_location:type()),
+      list(btl_direction:enum()),
+      btl_location:type()
+   )
+   -> {btl_location:type(), non_neg_integer()}.
+cross (Battlemap, ForbiddenLocations, Path, Location) ->
+   cross(Battlemap, ForbiddenLocations, Path, 0, Location).
diff --git a/src/battle/game-logic/btl_next_turn.erl b/src/battle/game-logic/btl_next_turn.erl
new file mode 100644
index 0000000..82eec98
--- /dev/null
+++ b/src/battle/game-logic/btl_next_turn.erl
@@ -0,0 +1,160 @@
+-module(btl_next_turn).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      update_if_needed/1
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec set_player_turn_to_next (btl_battle:type())
+   -> {btl_battle:type(), sh_db_query:op()}.
+set_player_turn_to_next (Battle) ->
+   Players = btl_battle:get_players(Battle),
+   CurrentPlayerTurn = btl_battle:get_current_player_turn(Battle),
+
+   NextPlayerTurn = btl_player_turn:next(Players, CurrentPlayerTurn),
+
+   UpdatedBattle = btl_battle:set_current_player_turn(NextPlayerTurn, Battle),
+
+   DBQuery =
+      sh_db_query:set_field
+      (
+         btl_battle:get_current_player_turn_field(),
+         NextPlayerTurn
+      ),
+
+   {UpdatedBattle, DBQuery}.
+
+-spec reset_next_player_timeline (btl_battle:type())
+   -> {btl_battle:type(), btl_player:type(), sh_db_query:op()}.
+reset_next_player_timeline (Battle) ->
+   NextPlayerTurn = btl_battle:get_current_player_turn(Battle),
+   NextPlayerIX = btl_player_turn:get_player_ix(NextPlayerTurn),
+   NextPlayer = btl_battle:get_player(NextPlayerIX, Battle),
+
+   UpdatedNextPlayer = btl_player:reset_timeline(NextPlayer),
+   UpdatedBattle =
+      btl_battle:set_player(NextPlayerIX, UpdatedNextPlayer, Battle),
+
+   DBQuery =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_players_field(),
+         NextPlayerIX,
+         [ sh_db_query:set_field(btl_player:get_timeline_field(), []) ]
+      ),
+
+   {UpdatedBattle, UpdatedNextPlayer, DBQuery}.
+
+
+-spec activate_next_players_characters (btl_battle:type(), btl_player:type())
+   -> {btl_battle:type(), list(sh_db_query:op())}.
+activate_next_players_characters (Battle, NextPlayer) ->
+   NextPlayerIX = btl_player:get_index(NextPlayer),
+   Characters = btl_battle:get_characters(Battle),
+
+   {UpdatedCharacters, ModifiedIXs} =
+      sh_array_util:mapiff
+      (
+         fun (Character) ->
+            (btl_character:get_player_index(Character) == NextPlayerIX)
+         end,
+         fun (Character) ->
+            btl_character:set_is_active(true, Character)
+         end,
+         Characters
+      ),
+
+   DBQueries =
+      lists:map
+      (
+         fun (IX) ->
+            sh_db_query:update_indexed
+            (
+               btl_battle:get_characters_field(),
+               IX,
+               [
+                  sh_db_query:set_field
+                  (
+                     btl_character:get_is_active_field(),
+                     true
+                  )
+               ]
+            )
+         end,
+         ModifiedIXs
+      ),
+
+   UpdatedBattle = btl_battle:set_characters(UpdatedCharacters, Battle),
+
+   {UpdatedBattle, DBQueries}.
+
+-spec update
+   (
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+update (Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+
+   {S0Battle, DBQuery0} = set_player_turn_to_next(Battle),
+   {S1Battle, NextPlayer, DBQuery1} = reset_next_player_timeline(S0Battle),
+   {S2Battle, DBQueries} =
+      activate_next_players_characters(S1Battle, NextPlayer),
+
+   S0Data = btl_character_turn_data:set_battle(S2Battle, Data),
+   S0Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         btl_turn_result:new_player_turn_started
+         (
+            btl_player:get_index(NextPlayer)
+         ),
+         DBQuery0,
+         Update
+      ),
+
+   S1Update = btl_character_turn_update:set_data(S0Data, S0Update),
+
+   S2Update =
+      lists:foldl
+      (
+         fun btl_character_turn_update:add_to_db/2,
+         S1Update,
+         [DBQuery1|DBQueries]
+      ),
+
+   S2Update.
+
+-spec requires_update (btl_character_turn_update:type()) -> boolean().
+requires_update (Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Characters = btl_battle:get_characters(Battle),
+
+   sh_array_util:none(fun btl_character:get_is_active/1, Characters).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec update_if_needed
+   (
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+update_if_needed (Update) ->
+   case requires_update(Update) of
+      true -> update(Update);
+      _ -> Update
+   end.
diff --git a/src/battle/game-logic/btl_turn_actions.erl b/src/battle/game-logic/btl_turn_actions.erl
new file mode 100644
index 0000000..21205ac
--- /dev/null
+++ b/src/battle/game-logic/btl_turn_actions.erl
@@ -0,0 +1,391 @@
+-module(btl_turn_actions).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle/2
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%% SWITCHING WEAPON %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle_switch_weapon
+   (
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_switch_weapon (Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   CharacterAttributes = btl_character:get_attributes(Character),
+   ArmorID = btl_character:get_armor_id(Character),
+   {PrimaryWeaponID, SecondaryWeaponID} = btl_character:get_weapon_ids(Character),
+
+   UpdatedWeaponIDs = {SecondaryWeaponID, PrimaryWeaponID},
+   UpdatedCharacterStatistics =
+      sh_statistics:new(CharacterAttributes, UpdatedWeaponIDs, ArmorID),
+   UpdatedCharacter =
+      btl_character:set_statistics
+      (
+         UpdatedCharacterStatistics,
+         btl_character:set_weapon_ids(UpdatedWeaponIDs, Character)
+      ),
+
+   TimelineItem = btl_turn_result:new_character_switched_weapons(CharacterIX),
+
+   DBQuery =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_characters_field(),
+         CharacterIX,
+         [
+            sh_db_query:set_field
+            (
+               btl_character:get_weapons_field(),
+               UpdatedWeaponIDs
+            ),
+            sh_db_query:set_field
+            (
+               btl_character:get_statistics_field(),
+               UpdatedCharacterStatistics
+            )
+         ]
+      ),
+
+   UpdatedData = btl_character_turn_data:set_character(UpdatedCharacter, Data),
+
+   S0Update = btl_character_turn_update:set_data(UpdatedData, Update),
+
+   btl_character_turn_update:add_to_timeline(TimelineItem, DBQuery, S0Update).
+
+%%%% MOVING %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec get_path_cost_and_destination
+   (
+      btl_character_turn_data:type(),
+      list(btl_direction:type())
+   )
+   -> {non_neg_integer(), btl_location:type()}.
+get_path_cost_and_destination (Data, Path) ->
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Battlemap = btl_battle:get_battlemap(Battle),
+
+   ForbiddenLocations =
+      array:foldl
+      (
+         fun (IX, Char, Prev) ->
+            IsAlive = btl_character:get_is_alive(Char),
+            if
+               (IX == CharacterIX) -> Prev;
+               (not IsAlive) -> Prev;
+               true -> [btl_character:get_location(Char)|Prev]
+            end
+         end,
+         [],
+         btl_battle:get_characters(Battle)
+      ),
+
+   {NewLocation, Cost} =
+      btl_movement:cross
+      (
+         Battlemap,
+         ForbiddenLocations,
+         Path,
+         btl_character:get_location(Character)
+      ),
+
+   {Cost, NewLocation}.
+
+-spec assert_character_can_move
+   (
+      btl_character_turn_data:type(),
+      non_neg_integer()
+   )
+   -> 'ok'.
+assert_character_can_move (Data, Cost) ->
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterStatistics = btl_character:get_statistics(Character),
+   CharacterMovementPoints =
+      sh_statistics:get_movement_points(CharacterStatistics),
+
+   true = (Cost =< CharacterMovementPoints),
+
+   ok.
+
+-spec commit_move
+   (
+      btl_character_turn_update:type(),
+      list(btl_direction:type()),
+      btl_location:type()
+   )
+   -> btl_character_turn_update:type().
+commit_move (Update, Path, NewLocation) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+
+   UpdatedCharacter = btl_character:set_location(NewLocation, Character),
+
+   UpdatedData = btl_character_turn_data:set_character(UpdatedCharacter, Data),
+
+   TimelineItem =
+      btl_turn_result:new_character_moved(CharacterIX, Path, NewLocation),
+
+   DBQuery =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_characters_field(),
+         CharacterIX,
+         [
+            sh_db_query:set_field
+            (
+               btl_character:get_location_field(),
+               NewLocation
+            )
+         ]
+      ),
+
+   S0Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         TimelineItem,
+         DBQuery,
+         Update
+      ),
+
+   btl_character_turn_update:set_data(UpdatedData, S0Update).
+
+-spec handle_move
+   (
+      btl_battle_action:type(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_move (BattleAction, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Path = btl_battle_action:get_path(BattleAction),
+
+   {PathCost, NewLocation} = get_path_cost_and_destination(Data, Path),
+   assert_character_can_move(Data, PathCost),
+
+   commit_move(Update, Path, NewLocation).
+
+%%%% ATTACKING %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle_attack_sequence
+   (
+      btl_character:type(),
+      btl_character:type(),
+      list(btl_attack:step())
+   )
+   -> {list(btl_attack:type()), non_neg_integer(), non_neg_integer()}.
+handle_attack_sequence
+(
+   Character,
+   TargetCharacter,
+   AttackSequence
+) ->
+   AttackPlannedEffects =
+      lists:map
+      (
+         fun (AttackStep) ->
+            btl_attack:get_description_of
+            (
+               AttackStep,
+               Character,
+               TargetCharacter
+            )
+         end,
+         AttackSequence
+      ),
+
+   lists:foldl
+   (
+      fun
+      (
+         AttackEffectCandidate,
+         {AttackValidEffects, AttackerHealth, DefenderHealth}
+      ) ->
+         {AttackResult, NewAttackerHealth, NewDefenderHealth} =
+            btl_attack:apply_to_healths
+            (
+               AttackEffectCandidate,
+               AttackerHealth,
+               DefenderHealth
+            ),
+         case AttackResult of
+            nothing -> {AttackValidEffects, AttackerHealth, DefenderHealth};
+            _ ->
+               {
+                  (AttackValidEffects ++ [AttackResult]),
+                  NewAttackerHealth,
+                  NewDefenderHealth
+               }
+         end
+      end,
+      {
+         [],
+         btl_character:get_current_health(Character),
+         btl_character:get_current_health(TargetCharacter)
+      },
+      AttackPlannedEffects
+   ).
+
+-spec get_attack_sequence
+   (
+      btl_character:type(),
+      btl_character:type()
+   )
+   -> list(btl_attack:step()).
+get_attack_sequence (Character, TargetCharacter) ->
+   Range =
+      btl_location:dist
+      (
+         btl_character:get_location(Character),
+         btl_character:get_location(TargetCharacter)
+      ),
+
+   {AttackingWeaponID, _} = btl_character:get_weapon_ids(Character),
+   {DefendingWeaponID, _} = btl_character:get_weapon_ids(TargetCharacter),
+
+   AttackingWeapon = sh_weapon:from_id(AttackingWeaponID),
+   DefendingWeapon = sh_weapon:from_id(DefendingWeaponID),
+
+   btl_attack:get_sequence(Range, AttackingWeapon, DefendingWeapon).
+
+
+-spec handle_attack
+   (
+      btl_battle_action:type(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_attack (BattleAction, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Character = btl_character_turn_data:get_character(Data),
+   CharacterIX = btl_character_turn_data:get_character_ix(Data),
+   TargetIX = btl_battle_action:get_target_ix(BattleAction),
+   TargetCharacter = btl_battle:get_character(TargetIX, Battle),
+
+   true = btl_character:get_is_alive(TargetCharacter),
+
+   AttackSequence = get_attack_sequence(Character, TargetCharacter),
+
+   {AttackEffects, RemainingAttackerHealth, RemainingDefenderHealth} =
+      handle_attack_sequence(Character, TargetCharacter, AttackSequence),
+
+   UpdatedCharacter =
+      btl_character:set_current_health(RemainingAttackerHealth, Character),
+
+   UpdatedBattle =
+      btl_battle:set_character
+      (
+         TargetIX,
+         btl_character:set_current_health
+         (
+            RemainingDefenderHealth,
+            TargetCharacter
+         ),
+         Battle
+      ),
+
+   S0Data = btl_character_turn_data:set_battle(UpdatedBattle, Data),
+   S1Data = btl_character_turn_data:set_character(UpdatedCharacter, S0Data),
+
+   TimelineItem =
+      btl_turn_result:new_character_attacked
+      (
+         CharacterIX,
+         TargetIX,
+         AttackEffects
+      ),
+
+   DBQuery0 =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_characters_field(),
+         TargetIX,
+         [
+            sh_db_query:set_field
+            (
+               btl_character:get_current_health_field(),
+               RemainingDefenderHealth
+            )
+         ]
+      ),
+
+   DBQuery1 =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_characters_field(),
+         CharacterIX,
+         [
+            sh_db_query:set_field
+            (
+               btl_character:get_current_health_field(),
+               RemainingAttackerHealth
+            )
+         ]
+      ),
+
+   S0Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         TimelineItem,
+         DBQuery0,
+         Update
+      ),
+
+   S1Update =
+      btl_character_turn_update:add_to_db
+      (
+         DBQuery1,
+         S0Update
+      ),
+
+   S2Update = btl_character_turn_update:set_data(S1Data, S1Update),
+
+   S3Update =
+      btl_victory:handle_character_lost_health
+      (
+         CharacterIX,
+         RemainingAttackerHealth,
+         S2Update
+      ),
+
+   S4Update =
+      btl_victory:handle_character_lost_health
+      (
+         TargetIX,
+         RemainingDefenderHealth,
+         S3Update
+      ),
+
+   S4Update.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle
+(
+   btl_battle_action:type(),
+   btl_character_turn_update:type()
+)
+-> btl_character_turn_update:type().
+handle (BattleAction, Update) ->
+   case btl_battle_action:get_category(BattleAction) of
+      move -> handle_move(BattleAction, Update);
+      switch_weapon -> handle_switch_weapon(Update);
+      attack -> handle_attack(BattleAction, Update)
+   end.
diff --git a/src/battle/game-logic/btl_victory.erl b/src/battle/game-logic/btl_victory.erl
new file mode 100644
index 0000000..eef42ad
--- /dev/null
+++ b/src/battle/game-logic/btl_victory.erl
@@ -0,0 +1,194 @@
+-module(btl_victory).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% TYPES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-export
+(
+   [
+      handle_character_lost_health/3
+   ]
+).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% LOCAL FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+-spec mark_players_characters_as_defeated
+   (
+      non_neg_integer(),
+      array:array(btl_character:type())
+   ) -> {array:array(btl_character:type()), list(non_neg_integer())}.
+mark_players_characters_as_defeated (PlayerIX, Characters) ->
+   sh_array_util:mapiff
+   (
+      fun (Character) ->
+         (btl_character:get_player_index(Character) == PlayerIX)
+      end,
+      fun (Character) ->
+         btl_character:set_is_defeated(true, Character)
+      end,
+      Characters
+   ).
+
+-spec add_db_query_to_mark_character_as_defeated
+   (
+      non_neg_integer(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+add_db_query_to_mark_character_as_defeated (IX, Update) ->
+   btl_character_turn_update:add_to_db
+   (
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_characters_field(),
+         IX,
+         [
+            sh_db_query:set_field
+            (
+               btl_character:get_is_defeated_field(),
+               true
+            )
+         ]
+      ),
+      Update
+   ).
+
+-spec handle_player_defeat
+   (
+      non_neg_integer(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_player_defeat (PlayerIX, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Characters = btl_battle:get_characters(Battle),
+
+   %% FIXME: The controlled character might slip through.
+   {UpdatedCharacters, ModifiedIXs} =
+      mark_players_characters_as_defeated(PlayerIX, Characters),
+
+   S1Update =
+      lists:foldl
+      (
+         fun add_db_query_to_mark_character_as_defeated/2,
+         Update,
+         ModifiedIXs
+      ),
+
+   %% TODO: Battle.player[PlayerIX].is_active <- false
+
+   UpdatedBattle = btl_battle:set_characters(UpdatedCharacters, Battle),
+   UpdatedData = btl_character_turn_data:set_battle(UpdatedBattle, Data),
+   S2Update = btl_character_turn_update:set_data(UpdatedData, S1Update),
+
+   DBQuery =
+      sh_db_query:update_indexed
+      (
+         btl_battle:get_players_field(),
+         PlayerIX,
+         [
+            sh_db_query:set_field
+            (
+               btl_player:get_is_active_field(),
+               false
+            )
+         ]
+      ),
+
+   S3Update =
+      btl_character_turn_update:add_to_timeline
+      (
+         btl_turn_result:new_player_lost(PlayerIX),
+         DBQuery,
+         S2Update
+      ),
+
+   S3Update.
+
+
+-spec actually_handle_character_lost_health
+   (
+      non_neg_integer(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+actually_handle_character_lost_health (CharIX, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   Battle = btl_character_turn_data:get_battle(Data),
+   Character = btl_battle:get_character(CharIX, Battle),
+   Characters = btl_battle:get_characters(Battle),
+   CharacterPlayerIX = btl_character:get_player_index(Character),
+
+   case btl_character:get_rank(Character) of
+      optional ->
+         %% Let's not assume there is a commander
+         StillHasAliveChar =
+            sh_array_util:any_indexed
+            (
+               fun (IX, Char) ->
+                  (
+                     (CharacterPlayerIX == btl_character:get_player_index(Char))
+                     and (IX /= CharIX)
+                     and btl_character:get_is_alive(Char)
+                  )
+               end,
+               Characters
+            ),
+
+         case StillHasAliveChar of
+            true -> Update;
+            _ -> handle_player_defeat(CharacterPlayerIX, Update)
+         end;
+
+      commander -> handle_player_defeat(CharacterPlayerIX, Update);
+
+      target ->
+         StillHasAliveChar =
+            sh_array_util:any_indexed
+            (
+               fun (IX, Char) ->
+                  (
+                     (CharacterPlayerIX == btl_character:get_player_index(Char))
+                     and (IX /= CharIX)
+                     and btl_character:get_is_alive(Char)
+                     and (btl_character:get_rank(Char) == target)
+                  )
+               end,
+               Characters
+            ),
+
+         case StillHasAliveChar of
+            true -> Update;
+            _ -> handle_player_defeat(CharacterPlayerIX, Update)
+         end
+   end.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EXPORTED FUNCTIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+-spec handle_character_lost_health
+   (
+      non_neg_integer(),
+      integer(),
+      btl_character_turn_update:type()
+   )
+   -> btl_character_turn_update:type().
+handle_character_lost_health (_, Health, Update) when (Health > 0) -> Update;
+handle_character_lost_health (CharIX, _Health, Update) ->
+   Data = btl_character_turn_update:get_data(Update),
+   S1Data = btl_character_turn_data:clean_battle(Data),
+   S1Update = btl_character_turn_update:set_data(S1Data, Update),
+
+   S2Update = actually_handle_character_lost_health(CharIX, S1Update),
+
+   S2Data = btl_character_turn_update:get_data(S2Update),
+   S3Data = btl_character_turn_data:refresh_character(S2Data),
+   S3Update = btl_character_turn_update:set_data(S3Data, S2Update),
+
+   S3Update.